Simulation von Random walks mit verschiedenen Inkrementverteilungen

nmax=10000;
(* maximale Schrittzahl *)

x=RandomChoice[{-1,1},nmax];
(* erzeugt nmax Inkremente eines klassischen Random Walks *)
z=RandomReal[NormalDistribution[0,1],nmax];
(* erzeugt nmax unabhängige Stichproben von N(0,1) *)
u=RandomReal[{0,1},nmax]; y=-Log[u]-1;
(* erzeugt nmax unabhängige Stichproben von der zentrierten, d.h. um -1 verschobenen, Exp(1)-Verteilung *)
α=3/2;x0=α-1;p=RandomReal[ParetoDistribution[x0,α],nmax];m=Mean[ParetoDistribution[x0,α]];q=p-m;
(* erzeugt nmax unabhängige zentrierte Stichproben von der Pareto((Subscript[x, 0]),α)-Verteilung mit Verteilungsfunktion F(x)=(SuperPlus[(1-(((x/(Subscript[x, 0])))^(-α)))])*)
(* Der Parameter (Subscript[x, 0]) ist dabei so gewählt,daß die Verteilung der zentrierten Stichproben oberhalb von(-1) liegt *)

Im Gegensatz zu den anderen Verteilungen fällt die Dichte f(x)=α (Subscript[x, 0]^α) (x^(-1-α))×(Subscript[I, [(Subscript[x, 0]),∞)])(x) der Pareto-Verteilung für x->∞ nur sehr langsam ab ("heavy tails"). Insbesondere hat die Verteilung für α≤2 unendliche Varianz. Die folgende Grafik zeigt die Dichten der (zentrierten) Inkrementverteilungen:

Plot[{PDF[NormalDistribution[0,1],x],PDF[ExponentialDistribution[1],x+1],PDF[ParetoDistribution[x0,α],x+m]},{x,-2,5}]

rwsimple=Accumulate[x];rwexp=Accumulate[y];rwnormal=Accumulate[z]; rwpareto=Accumulate[q];
(* erzeugt Trajektorien der Random walks mit den verschiedenen Inkrementverteilungen *)

ListLinePlot[{rwsimple[[1;;3000]],rwexp[[1;;3000]],rwnormal[[1;;3000]],rwpareto[[1;;3000]]}]

Die Trajektorien des klassischen Random Walks, und der Random Walks mit exponential- und normalverteilten Inkrementen sehen in größeren Zeiträumen ähnlich aus. Die Trajektorien des Pareto-Random Walks (grün) verhalten sich dagegen anders, und werden auch in längeren Zeiträumen von einzelnen grossen Sprüngen beeinflusst. Tatsächlich kann man zeigen, dass alle obigen Random Walks mit Ausnahme des Pareto-Random Walks in einem geeigneten Skalierungslimes mit Schrittweite gegen 0 in Verteilung gegen eine Brownsche Bewegung konvergieren (funktionaler zentraler Grenzwertsatz).

Manipulate[ListLinePlot[{rwsimple[[1;;n]],rwexp[[1;;n]],rwnormal[[1;;n]],rwpareto[[1;;n]]}],{{n,50},1,nmax,1}]